home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #1 / Ham Radio 2000.iso / ham2000 / packet / thenet / x1j4_src / pk96.c < prev    next >
Encoding:
C/C++ Source or Header  |  1995-01-02  |  13.9 KB  |  504 lines
  1. /*****************************************************************************/
  2. /*                                              */
  3. /*                                         */
  4. /*    *****              *****                      */
  5. /*     *****            *****                         */
  6. /*       *****          *****                         */
  7. /*         *****        *****                         */
  8. /*  ***************      ***************                     */
  9. /*  *****************    *****************                     */
  10. /*  ***************      ***************                     */
  11. /*         *****        *****       TheNet                    */
  12. /*       *****          *****       Portable. Compatible.         */
  13. /*     *****            *****       Public Domain             */
  14. /*    *****              *****    G8KBB                  */
  15. /*                                         */
  16. /* This software is public domain ONLY for non commercial use                */
  17. /*                                                                           */
  18. /*                                         */
  19. /*****************************************************************************/
  20.  
  21. /* 
  22.  * released as TheNet X-1J September 1993
  23.  *
  24.  * Modified for PK-96
  25.  */
  26.  
  27. #ifdef BANKED
  28. #define EXTERN
  29. #define VARIABLES
  30. #include "all.h"
  31. #include "tntyp.h"
  32. #include "tnl3v.h"
  33. #include "tnl4v.h"
  34. #include "miscv.h"
  35. #include "tnl7av.h"
  36. #ifdef IPROUTE
  37. #include "ip.h"
  38. #include "ipv.h"
  39. #endif
  40.  
  41. char    nulide[] =                /* leerer Ident             */
  42.                    {' ',' ',' ',' ',' ',' '};
  43.  
  44. char    beades[] = { 'I','D',' ',' ',' ',' ','\140' }; /* Call fuer Bake     */
  45. char    cqdest[] = { 'C','Q',' ',' ',' ',' ','\140' }; /* Call fuer CQ-Ruf   */
  46. char    cqdil[]  = "";                    /* Digiliste fuer CQ-Ruf */
  47. char    L4audit[] = "L4    `";
  48. char    L2audit[] = "L2    `";
  49.  
  50. #ifdef MANAGED
  51. char AudCon[] = "C ";
  52. char AudConAcc[] = "CA";
  53. char AudDisc[] = "D ";
  54. char AudDiscAcc[] = "DA";
  55. #endif
  56.  
  57. #ifdef PORTABLE
  58.  
  59. /* ***********************************************************************
  60.  * The timer() routine is called every 10 milliseconds.
  61.  * The portable version does NOT support the ancilliary
  62.  * functions of l1 stats and cwid
  63.  */
  64.  
  65. VOID timer()
  66. {
  67.     ++tic10;
  68. }
  69.  
  70. /* ***********************************************************************
  71.  * The stop() routine is used to halt the system upon
  72.  * closedown. WARNING - the portable version does not
  73.  * correctly initialise the SIO - so it may stop with
  74.  * the ptt enabled !!!!!! ( it's really only there for
  75.  * test purposes. )
  76.  */
  77.  
  78. VOID stop()
  79. {
  80.     DIinc();
  81. loop:    kick_wdog();
  82.     goto loop;
  83. }
  84.  
  85. #else
  86. #asm
  87.     .64180
  88. SIADAT    equ    07fh
  89. SIACTL    equ    07eh
  90. SIBDAT    equ    07dh
  91. SIBCTL    equ     07ch
  92. PTT    equ    0b0h
  93. MODEM_SEL equ    0b6h
  94.  
  95. ;  ***********************************************************************
  96. ;  The stop() routine is used to halt the system upon
  97. ;  closedown. 
  98. ; 
  99.     extrn    SIAIW5    ; , SIBIW5
  100.     extrn    kick_wdog_
  101.  
  102.     public    stop_
  103. stop_:
  104.     di
  105.     ld    A,5
  106.     out    (SIACTL),A
  107.     ld    A,(SIAIW5)    ; turn off modem tone
  108.     out    (SIACTL),A
  109.     xor    A        ; switch off PTT
  110.     out0    (PTT),A
  111. ;    ld    A,5
  112. ;    out    (SIBCTL),A
  113. ;    ld    A,(SIBIW5)
  114. ;    out    (SIBCTL),A
  115. stoploop:
  116.     call    kick_wdog_
  117.     jr    stoploop
  118.  
  119. ; ***********************************************************************
  120. ; The timer() routine is called every 10 milliseconds.
  121. ; The non portable version supports the ancilliary
  122. ; functions of l1 stats and cwid
  123. ;
  124.  
  125.     public timer_
  126.     extrn tic10_, SIAWR5, SIARR0, txon_, dcdon_, SIAIW5
  127.     extrn cwtimr_
  128.  
  129. timer_:    
  130.     ld    hl,(tic10_)    ; bump the 10 millisecond counter
  131.     inc    hl
  132.     ld    (tic10_), hl
  133. #endasm
  134. #ifdef STATSCMD
  135. #asm
  136.     ld    a,(SIAWR5)    ; test for RTS on HDLC port, ie PTT is ON
  137.     bit    1,a        ; ( ie the rig is on xmit )
  138.     jr    z,td        ; If not, go try the receiver
  139.     ld    hl,(txon_)    ; If so, bump the TX on counter
  140.     inc    hl
  141.     ld    (txon_),hl
  142. td:    ld    a,(SIARR0)    ; Now check the DCD line
  143.     bit    3,a        ; to see if the RX is on
  144.     jr    z,rd        ; If not, skip over
  145.     ld    hl,(dcdon_)    ; If so, bump DCD counter
  146.     inc    hl
  147.     ld    (dcdon_),hl
  148. rd:
  149. #endasm
  150. #endif
  151. #ifdef CWID
  152. #asm
  153.     ld    A,(cwtimr_)    ; ckeck CW timer. Zero means it is not running
  154.     or    A        ; so if it tests zero, just skip over.
  155.     jr    z,timer0
  156.     dec    A        ; If it is not zero, then decrement it and
  157.     ld    (cwtimr_),A    ; store the new value. Also, if it has
  158.     call     Z,cwidbit    ; reached zero, then go get the next bit
  159. #endasm
  160. #endif
  161. #asm
  162. timer0:    ret
  163. #endasm
  164.  
  165. #endif    /* PORTABLE */
  166.  
  167. #endif    /* BANKED */
  168.  
  169. /* ***********************************************************************
  170.  * The cwid() routine is called by the timer() function
  171.  * if calibrating or cwid in progress to do the next bit 
  172.  */
  173.  
  174. #ifdef CWID
  175. #asm
  176.     .64180
  177.     extrn    cwstate_, cwbit_, cwofs_, cwdat_, cwch_, cwtimr_, cwspeed_
  178.     extrn    xFpar_, Dpar_, HRXRES, HTXSTA, SIAINI, SIAIEN, modem_type
  179.     extrn   modem_init
  180.  
  181.     global calper_,1
  182.     global caltog_,1
  183.     global caltog,1
  184.  
  185. cwidbit:
  186.     ld    HL,cwstate_    ; POINT TO STATE REGISTER
  187.     ld    A,(HL)        ; CHECK CURRENT STATE
  188.     cp    80h        ; if 80h, then we are calibrating
  189.     jp    z, calib
  190.     cp    0        ; if 0, fall thru the next jumps...
  191.     jp    M,cwbitx    ; If '-1', awaiting start of send
  192.     jr    NZ,cwbit2    ; If not zero ( 1 or 2 ) sending a delay
  193.     ld    A,(cwbit_)    ; read current char bits remaining counter
  194.     or    A        ; check if at end ( ie zero )
  195.     jr    NZ,cwbit0    ; if not, continue sending this char
  196.     ld    A,(cwofs_)    ; otherwise we need the next char, so get offs
  197.     inc    A        ; and point to the next character
  198.     ld    (cwofs_),A    ; store new offset for next time
  199.     ld    HL,cwdat_    ; now add offset to start of data table
  200.     ld    E,A
  201.     ld    D,0
  202.     add    HL,DE        ; so HL now points to next data entry
  203.     ld    A,(HL)        ; and read from it the character data,
  204.     and    1fh        ; which is in the lower 5 bits only.
  205.     ld    (cwch_),A    ; and store it in the char holding variable
  206.     ld    A,(HL)        ; get character again for the bits variable
  207.     rla            ; move the contents of the top 3 bits to
  208.     rla            ; the bottom 3 bits of the accumulator
  209.     rla            ; so that the number of bits is in
  210.     rla            ; the low 3 bits of A.
  211.     and    7        ; Now select only the 3 bits
  212.     ld    (cwbit_),A    ; store bit count
  213.     or    A        ; If zero, we are at the end of the callsign
  214.     ld    A,0        ; (just extend the delay if end of character)
  215.     jr    NZ,cwbit7    ; if not end of call, send inter char delay
  216.     ld    A,2        ; signal end of callsign by setting state to 2
  217. cwbit7:    ld    (cwstate_),A    ; and dropping thru into the delay anyway.
  218.     ld    A,(cwspeed_)    ; send a two bit delay period by reading speed
  219.     sla    A        ; doubling it and setting the tick timer
  220.     jr    cwbit3
  221.  
  222. cwbit0:    dec    A        ; continue sending this char, decrement bit
  223.     ld    (cwbit_),A    ; counter and store it
  224.     ld    A,1        ; set state to '1' for next time round
  225.     ld    (HL),A
  226.     ld    HL,cwspeed_    ; point to CWID speed bit value
  227.     ld    A,(cwch_)    ; read current character data
  228.     ld    E,A        ; store it in E temporarily
  229.     bit    0,E        ; check if LSB set. If so DASH not DOT
  230.     ld    A,(HL)        ; set speed as for a dot
  231.     jr    Z,cwbit1    ; and if it was a dash fall thru and treble it
  232.     sla    A        ; by doubling and
  233.     add    A,(HL)        ; adding the original again
  234. cwbit1:    ld    D,A        ; put delay period value in D temorarily
  235.     scf            ; set carry flag as parameter to ...
  236.     call    modem_tone    ; ... turn on the modem tone
  237.     ld    A,E        ; get current character data back again
  238.     srl    A        ; move to the next bit
  239.     ld    (cwch_),A    ; and restore the character data
  240.     ld    A,D        ; get delay period back again
  241.     jr    cwbit3
  242.  
  243. cwbit2:    scf
  244.     ccf            ; clear carry flag as parameter to modem_tone
  245.     call    modem_tone    ; to switch off the 1200 baud modem tone
  246.     dec    A        ; A contains state. If it was 1, go to cwbit4
  247.     jr    Z,cwbit4    ; otherwise fall thru to 'stop'
  248.  
  249. ; cwstop
  250.  
  251. cwstop:    ld    A,3        ; state 3 means 'i have finished'.
  252.     ld    (cwstate_),A
  253.     ld    HL,SIAINI    ; reset and initialise the channel.
  254.     ld    BC,SIACTL or ((SIAIEN-SIAINI)<<8)
  255.     otir
  256.     xor    A        ; next state of the HDLC Tx is 'idle'
  257.     ld    (HTXSTA),A
  258.     out0    (PTT),A        ; kill PTT signal
  259.     ld    A,(modem_type)    ; select the right modem type
  260.     out0    (MODEM_SEL),A
  261.     ld    A,12        ; access SCC register 12 ( brate low )
  262.     out    (SIACTL),A
  263.     ld    A,(modem_init)    ; get baud rate generator init value
  264.     out    (SIACTL),A    ; and change it back to what it was
  265.     ld    A,(SIAIW5)    ; set SIAWR5 image to initial value
  266.     ld    (SIAWR5),A
  267.     ld    A,5        ; access write register 5
  268.     out    (SIACTL),A
  269.     ld    HL,SIAWR5
  270.     res    1,(HL)        ; and kill the tone ( will be off anyway )
  271.     ld    A,(xFpar_)
  272.     or    A
  273.     jr    NZ,cwstop0
  274.     res    3,(HL)
  275. cwstop0:
  276.     ld    A,(HL)
  277.     out    (SIACTL),A
  278.     ld    A,(Dpar_)
  279.     or    A
  280.     call    Z,HRXRES
  281.     jr    cwbitx
  282.  
  283. ; delay sending routine
  284.  
  285. cwbit4:    ld    (HL),A        ; set next state from A register
  286.     ld    A,(cwspeed_)    ; read cw speed value to give single dot delay
  287. cwbit3:    ld    (cwtimr_),A    ; set the timer count to required delay
  288. cwbitx:    ret
  289.  
  290.  
  291. ; ***********************************************************************
  292. ; helper routine for cwid bits - input parameter is carry flag.
  293. ; If set, turn tone on. If clear, turn tone off. Don't change
  294. ; registers !
  295.  
  296. modem_tone:
  297.     push    AF        ; save state number whilst changing tone
  298.     ld    A,5
  299.     out    (SIACTL),A    ; register 5 gives access to the ...
  300.     ld    A,(SIAWR5)    ; ... RTS bit to switch 1200 Hz modem tone off
  301.     res    1,A        ; clear bit 1 ( oe tone off )
  302.     jr    NC, moton1    ; and if carry set, ...
  303.     set    1,A        ; then turn it on !
  304. moton1:    ld    (SIAWR5),A    ; update WR5 image
  305.     out    (SIACTL),A    ; and output to SCC
  306.     pop    AF        ; restore state
  307.     ret
  308.  
  309. ; ***********************************************************************
  310. ; This is the TNC calibrate routine
  311. ; It is called by cwid function ( above ) instead of the cwid function
  312. ;
  313.  
  314. calib:    ld    hl,calper_    ; decrement the 1 second counter
  315.     dec    (hl)        ; If it is zero, then stop sending
  316.     jr    z,cwstop    ; Otherwise, continue another second
  317.     ld    hl,caltog    ; Now decrement the toggle period counter
  318.     dec    (hl)        ; and if it is zero
  319.     jr    nz,calib0
  320.     ld    a,(caltog_)    ; then reset the counter to the start value
  321.     ld    (hl),a
  322.     ld    a,0feh        ; and toggle the o/p tone
  323.     out    (SIADAT),a
  324. calib0:    ld    a,100        ; and wake me in 10ms * 100, ie 1 second
  325.     jr    cwbit3
  326.  
  327. ; ***********************************************************************
  328. ; The cwkick() routine is called by the level 1 xmit function SIATBE()
  329. ; register definitions are as per SIBTBE internal operation !
  330. ;
  331.  
  332. ; this is the initialisation data to reprogram the SCC for cwid or calib
  333. ; after the cwid of calibrate, the main initialisation will be repeated
  334. ; which includes a channel reset.
  335. ; The code below just nobbles it to give constant tone and kills interrupts.
  336. ; In full duplex mode, we stop receiving when CWIDing etc
  337.  
  338. SIACWI:    db    4,0,5
  339. SIACW5:    db    0eah
  340.     db    3,0d9h,6,0ffh,7,0ffh,1,00h,10h
  341. SIACIX:
  342.  
  343.     public    cwkick
  344.  
  345. cwkick:    ld    A,11        ; note that HL points to state ( see SIATBE )
  346.     ld    (HL),A        ; change state
  347.     ld    HL,SIACWI    ; now initialise SCC channel A
  348.     ld    BC,SIACTL or ((SIACIX-SIACWI)<<8)
  349.     otir
  350.     ld    A,(SIACW5)    ; set WR5 image to initial value
  351.     ld    (SIAWR5),A
  352.     in    A,(SIACTL)    ; initialise the RR0 image register
  353.     ld    (SIARR0),A
  354.     ld    A,1        ; switch PTT on
  355.     out0    (PTT),A
  356.     ld    A,(cwstate_)    ; see if we are to calibrate or cwid
  357.     cp    -2        ; state of (-2) means calibrate
  358.     jr    nz, cwkik0
  359.     ld    a,(caltog_)    ; initialise toggle period to the value
  360.     ld    (caltog),a    ; set by the sysop
  361.     ld    A,80h        ; set next state to 80h ( calibrating )
  362.     jr    cwkik1
  363. cwkik0:    ld    A,1        ; select the 1200 baud modem
  364.     out0    (MODEM_SEL),A
  365.     xor    A
  366.     scf
  367.     ccf            ; for CWID, start with silence, so...
  368.     call    modem_tone    ; turn OFF the modem tone ( silence )
  369. cwkik1:    ld    (cwstate_),A    ; wait for 500 milliseconds
  370.     ld    A,50
  371.     ld    (cwtimr_),A
  372.     ret
  373.  
  374. #endasm
  375. #endif
  376.  
  377.  
  378. /**************************************************************************\
  379. *                                                                          *
  380. * "copy memory from place to place"                                        *
  381. *                                                                          *
  382. * WARNING - ANSI version handles overlapping memory. this does not         *
  383. *                                                                          *
  384. \**************************************************************************/
  385. #ifndef PORTABLE
  386. #asm
  387.     public memcpy_        ;memcpy(dest,source,count)
  388. memcpy_:
  389.     push    bc        ; save BC register as we use it
  390.     ld    hl,9        ; point to top of params ( count )
  391.     add    hl,sp
  392.     ld    b,(hl)        ; BC contains count
  393.     dec    hl
  394.     ld    c,(hl)
  395.     dec    hl
  396.     ld    d,(hl)        ; DE contains destination for now
  397.     dec    hl
  398.     ld    e,(hl)
  399.     dec    hl
  400.     ld    a,(hl)
  401.     dec    hl
  402.     ld    l,(hl)        ; HL has source address but ....
  403.     ld    h,a
  404.     ex    de,hl        ; swap DE & HL registers
  405.     ldir
  406.     pop    bc
  407.     ret
  408.  
  409. #endasm
  410. #endif
  411.  
  412. /**************************************************************************\
  413. *                                                                          *
  414. * compare - "compare memory at two locations"                              *
  415. * cmpcal  - "compare two netrom aliases                                    *
  416. * cmpid   - "compare two callsigns                                         *
  417. *                                                                          *
  418. * WARNING - assembly versions of cmpid & cmpcal jump INTO this procedure ! *
  419. *                                                                          *
  420. \**************************************************************************/
  421. #ifndef PORTABLE
  422. #asm
  423.     public compare_        ;compare(id1, id2, count )
  424. compare_:
  425.     push    bc        ; save BC register as we use it
  426.     ld    hl,9        ; point to top of params ( count )
  427.     add    hl,sp
  428.     ld    b,(hl)        ; BC contains count
  429.     dec    hl
  430.     ld    c,(hl)
  431.     dec    hl
  432.     ld    d,(hl)        ; DE contains one address
  433.     dec    hl
  434.     ld    e,(hl)
  435.     dec    hl
  436.     ld    a,(hl)
  437.     dec    hl
  438.     ld    l,(hl)        ; HL has second address
  439.     ld    h,a
  440. c0:    ld    a,(de)
  441.     cpi
  442.     jr    nz, c1
  443.     inc    de
  444.     jp    pe,c0
  445. c4:    ld    hl,1
  446.     jr    c2
  447. c1:    ld    hl,0
  448. c2:    ld    a,h
  449.     or    l
  450.     pop    bc
  451.     ret
  452.  
  453.     public cmpcal_
  454. cmpcal_:    push bc
  455.     ld    hl,7        ; point to top of params ( count )
  456.     add    hl,sp
  457.     ld    d,(hl)        ; DE contains count
  458.     dec    hl
  459.     ld    e,(hl)
  460.     dec    hl
  461.     ld    a,(hl)
  462.     dec    hl
  463.     ld    l,(hl)        ; HL has second address
  464.     ld    h,a
  465.     ld     a,(de)
  466.     cp     32
  467.     jr    z,c1
  468.     ld    a,(hl)
  469.     cp    32
  470.     jr    z,c1
  471.     ld    bc,6
  472.     jr    c0
  473.  
  474.     public cmpid_
  475. cmpid_:    push bc
  476.     ld    hl,7        ; point to top of params ( count )
  477.     add    hl,sp
  478.     ld    d,(hl)        ; DE contains count
  479.     dec    hl
  480.     ld    e,(hl)
  481.     dec    hl
  482.     ld    a,(hl)
  483.     dec    hl
  484.     ld    l,(hl)        ; HL has second address
  485.     ld    h,a
  486.     ld    bc,6
  487. c3:    ld    a,(de)
  488.     cpi
  489.     jr    nz, c1
  490.     inc    de
  491.     jp    pe,c3
  492.     ld    a,(de)
  493.     and    30
  494.     ld    b,a
  495.     ld    a,(hl)
  496.     and    30
  497.     cp    b
  498.     jr    nz,c1
  499.     jr    c4
  500.  
  501.  
  502. #endasm
  503. #endif
  504.